1TEMPLATE = lib
2TARGET = dummy
3
4CONFIG -= debug_and_release
5
6WEBCORE_HEADERS_FOR_WEBKIT2 += \
7 bindings/js/DOMWrapperWorld.h \
8 bindings/js/GCController.h \
9 bindings/js/JSPluginElementFunctions.h \
10 bridge/IdentifierRep.h \
11 bridge/npapi.h \
12 bridge/npruntime.h \
13 config.h \
14 css/CSSComputedStyleDeclaration.h \
15 dom/Event.h \
16 dom/KeyboardEvent.h \
17 dom/Node.h \
18 dom/Range.h \
19 editing/EditCommand.h \
20 editing/EditorInsertAction.h \
21 editing/TextAffinity.h \
22 history/BackForwardControllerClient.h \
23 history/BackForwardList.h \
24 history/HistoryItem.h \
25 html/HTMLFormElement.h \
26 html/HTMLFrameOwnerElement.h \
27 html/HTMLPlugInElement.h \
28 inspector/InspectorClient.h \
29 loader/appcache/ApplicationCacheStorage.h \
30 loader/Cache.h \
31 loader/DocumentLoader.h \
32 loader/FormState.h \
33 loader/FrameLoaderClient.h \
34 loader/FrameLoader.h \
35 loader/FrameLoaderTypes.h \
36 loader/NetscapePlugInStreamLoader.h \
37 loader/PolicyChecker.h \
38 loader/ProgressTracker.h \
39 page/animation/AnimationController.h \
40 page/ChromeClient.h \
41 page/Chrome.h \
42 page/ContextMenuClient.h \
43 page/DragClient.h \
44 page/EditorClient.h \
45 page/EventHandler.h \
46 page/FocusController.h \
47 page/Frame.h \
48 page/FrameLoadRequest.h \
49 page/FrameView.h \
50 page/MediaCanStartListener.h \
51 page/PageGroup.h \
52 page/Page.h \
53 page/SecurityOrigin.h \
54 page/Settings.h \
55 page/WindowFeatures.h \
56 platform/Cursor.h \
57 platform/FileChooser.h \
58 platform/FileSystem.h \
59 platform/graphics/FloatRect.h \
60 platform/graphics/FontRenderingMode.h \
61 platform/graphics/GraphicsContext.h \
62 platform/graphics/GraphicsLayerClient.h \
63 platform/graphics/GraphicsLayer.h \
64 platform/graphics/IntPoint.h \
65 platform/graphics/IntRect.h \
66 platform/graphics/IntSize.h \
67 platform/HostWindow.h \
68 platform/KURL.h \
69 platform/LocalizationStrategy.h \
70 platform/MIMETypeRegistry.h \
71 platform/network/android/ResourceError.h \
72 platform/network/android/ResourceRequest.h \
73 platform/network/android/ResourceResponse.h \
74 platform/network/HTTPHeaderMap.h \
75 platform/PlatformKeyboardEvent.h \
76 platform/PlatformMouseEvent.h \
77 platform/PlatformStrategies.h \
78 platform/PlatformWheelEvent.h \
79 platform/PopupMenu.h \
80 platform/PopupMenuClient.h \
81 platform/SchemeRegistry.h \
82 platform/ScrollView.h \
83 platform/SearchPopupMenu.h \
84 platform/SharedBuffer.h \
85 platform/text/PlatformString.h \
86 platform/text/StringHash.h \
87 platform/Widget.h \
88 platform/win/BitmapInfo.h \
89 platform/WindowsKeyboardCodes.h \
90 platform/win/WebCoreInstanceHandle.h \
91 platform/win/WindowMessageBroadcaster.h \
92 platform/win/WindowMessageListener.h \
93 plugins/npfunctions.h \
94 plugins/PluginData.h \
95 plugins/PluginStrategy.h \
96 plugins/PluginViewBase.h \
97 rendering/RenderLayer.h \
98 rendering/RenderTreeAsText.h \
99
100WEBCORE_GENERATED_HEADERS_FOR_WEBKIT2 += \
101 $$OUTPUT_DIR/WebCore/generated/JSElement.h \
102 $$OUTPUT_DIR/WebCore/generated/JSCSSStyleDeclaration.h
103
104JSC_HEADERS_FOR_WEBKIT2 += \
105 API/APICast.h \
106 API/JavaScript.h \
107 API/JSBase.h \
108 runtime/Error.h \
109 runtime/FunctionPrototype.h \
110 runtime/InternalFunction.h \
111 runtime/JSGlobalObject.h \
112 runtime/JSLock.h \
113 runtime/JSObject.h \
114 runtime/JSObjectWithGlobalObject.h \
115 runtime/ObjectPrototype.h \
116 runtime/Protect.h \
117 wtf/Platform.h \
118 wtf/text/StringHash.h \
119
120WEBKIT2_API_HEADERS += \
121 UIProcess/API/C/WKAPICast.h \
122 UIProcess/API/C/WKBase.h \
123 UIProcess/API/C/WKContext.h \
124 UIProcess/API/C/WKContextPrivate.h \
125 UIProcess/API/C/WKFrame.h \
126 UIProcess/API/C/WKFramePolicyListener.h \
127 UIProcess/API/C/WKNavigationData.h \
128 UIProcess/API/C/WKPage.h \
129 UIProcess/API/C/WKPageNamespace.h \
130 UIProcess/API/C/WKPagePrivate.h \
131 UIProcess/API/C/WKPreferences.h \
132 UIProcess/API/C/WKString.h \
133 UIProcess/API/C/WKURL.h \
134 UIProcess/API/C/WebKit2.h \
135 UIProcess/API/cpp/WKRetainPtr.h \
136 UIProcess/API/qt/qgraphicswkview.h \
137 UIProcess/API/qt/qwkpage.h \
138 WebProcess/InjectedBundle/API/c/WKBundleBase.h \
139 WebProcess/InjectedBundle/API/c/WKBundlePage.h \
140
141
142QUOTE = ""
143DOUBLE_ESCAPED_QUOTE = ""
144ESCAPE = ""
145MKDIR = ""
146win32-msvc* {
147 ESCAPE = "^"
148 MKDIR = md
149} else symbian {
150 ESCAPE = "^"
151 MKDIR = mkdir
152} else:win32-g++*:isEmpty(QMAKE_SH) {
153 # MinGW's make will run makefile commands using sh, even if make
154 # was run from the Windows shell, if it finds sh in the path.
155 ESCAPE = "^"
156 MKDIR = md
157} else {
158 QUOTE = "\'"
159 DOUBLE_ESCAPED_QUOTE = "\\\'"
160 MKDIR = mkdir
161}
162
163DIRS = \
164 $$OUTPUT_DIR/include/JavaScriptCore \
165 $$OUTPUT_DIR/include/WebCore \
166 $$OUTPUT_DIR/include/WebKit2
167
168for(DIR, DIRS) {
169 !exists($$DIR): system($$MKDIR $$DIR)
170}
171
172QMAKE_EXTRA_TARGETS += createdirs
173
174SRC_ROOT_DIR = $$replace(PWD, /WebKit2, /)
175
176for(HEADER, WEBCORE_HEADERS_FOR_WEBKIT2) {
177 DESTDIR_BASE = "WebCore"
178
179 HEADER_NAME = $$basename(HEADER)
180 HEADER_PATH = $$SRC_ROOT_DIR/$$DESTDIR_BASE/$$HEADER
181 HEADER_TARGET = $$replace(HEADER_PATH, [^a-zA-Z0-9_], -)
182 HEADER_TARGET = "qtheader-$${HEADER_TARGET}"
183 DESTDIR = $$OUTPUT_DIR/include/$$DESTDIR_BASE
184
185 #FIXME: This should be organized out into a function
186 eval($${HEADER_TARGET}.target = $$DESTDIR/$$HEADER_NAME)
187 eval($${HEADER_TARGET}.depends = $$HEADER_PATH)
188 eval($${HEADER_TARGET}.commands = echo $${DOUBLE_ESCAPED_QUOTE}\$${LITERAL_HASH}include \\\"$$HEADER_PATH\\\"$${DOUBLE_ESCAPED_QUOTE} > $$eval($${HEADER_TARGET}.target))
189
190 QMAKE_EXTRA_TARGETS += $$HEADER_TARGET
191 generated_files.depends += $$eval($${HEADER_TARGET}.target)
192}
193
194for(HEADER, WEBCORE_GENERATED_HEADERS_FOR_WEBKIT2) {
195 HEADER_NAME = $$basename(HEADER)
196 HEADER_PATH = $$HEADER
197 HEADER_TARGET = $$replace(HEADER_PATH, [^a-zA-Z0-9_], -)
198 HEADER_TARGET = "qtheader-$${HEADER_TARGET}"
199 DESTDIR = $$OUTPUT_DIR/include/"WebCore"
200
201 eval($${HEADER_TARGET}.target = $$DESTDIR/$$HEADER_NAME)
202 eval($${HEADER_TARGET}.depends = $$HEADER_PATH)
203 eval($${HEADER_TARGET}.commands = echo $${DOUBLE_ESCAPED_QUOTE}\$${LITERAL_HASH}include \\\"$$HEADER_PATH\\\"$${DOUBLE_ESCAPED_QUOTE} > $$eval($${HEADER_TARGET}.target))
204
205 QMAKE_EXTRA_TARGETS += $$HEADER_TARGET
206 generated_files.depends += $$eval($${HEADER_TARGET}.target)
207}
208
209for(HEADER, JSC_HEADERS_FOR_WEBKIT2) {
210 DESTDIR_BASE = "JavaScriptCore"
211
212 HEADER_NAME = $$basename(HEADER)
213 HEADER_PATH = $$SRC_ROOT_DIR/$$DESTDIR_BASE/$$HEADER
214 HEADER_TARGET = $$replace(HEADER_PATH, [^a-zA-Z0-9_], -)
215 HEADER_TARGET = "qtheader-$${HEADER_TARGET}"
216 DESTDIR = $$OUTPUT_DIR/include/$$DESTDIR_BASE
217
218 eval($${HEADER_TARGET}.target = $$DESTDIR/$$HEADER_NAME)
219 eval($${HEADER_TARGET}.depends = $$HEADER_PATH)
220 eval($${HEADER_TARGET}.commands = echo $${DOUBLE_ESCAPED_QUOTE}\$${LITERAL_HASH}include \\\"$$HEADER_PATH\\\"$${DOUBLE_ESCAPED_QUOTE} > $$eval($${HEADER_TARGET}.target))
221
222 QMAKE_EXTRA_TARGETS += $$HEADER_TARGET
223 generated_files.depends += $$eval($${HEADER_TARGET}.target)
224}
225
226for(HEADER, WEBKIT2_API_HEADERS) {
227 DESTDIR_BASE = "WebKit2"
228
229 HEADER_NAME = $$basename(HEADER)
230 HEADER_PATH = $$PWD/$$HEADER
231 HEADER_TARGET = $$replace(HEADER_PATH, [^a-zA-Z0-9_], -)
232 HEADER_TARGET = "qtheader-$${HEADER_TARGET}"
233 DESTDIR = $$OUTPUT_DIR/include/$$DESTDIR_BASE
234
235 eval($${HEADER_TARGET}.target = $$DESTDIR/$$HEADER_NAME)
236 eval($${HEADER_TARGET}.depends = $$HEADER_PATH)
237 eval($${HEADER_TARGET}.commands = echo $${DOUBLE_ESCAPED_QUOTE}\$${LITERAL_HASH}include \\\"$$HEADER_PATH\\\"$${DOUBLE_ESCAPED_QUOTE} > $$eval($${HEADER_TARGET}.target))
238
239 QMAKE_EXTRA_TARGETS += $$HEADER_TARGET
240 generated_files.depends += $$eval($${HEADER_TARGET}.target)
241}
242
243QMAKE_EXTRA_TARGETS += generated_files